51mcu模拟PWM,可以控制3路同时不同占空比输出吗?
如题,这样就可以控制RGB彩灯了,求思路或链接,谢谢了 #include<reg52.h>#define uchar unsigned char
#define pt100 //调整这个参数改变频率
sbit RL=P0^0; //红灯亮度
sbit GL=P0^1; //绿灯亮度
sbit BL=P0^2; //蓝灯亮度
void delay()
{
uchar i;
for(i=0;i<pt;i++);
}
void keysearch()
{
}
void main()
{
uchari, t1=50,t2=100,t3=150 ,T=200; //
while(1)
{
keysearch();// 按键控制或其他控制来改变t1,t2,t3的大小,即三色灯高电平的持续时间.
for(i=0, RL=1,GL=1, BL=1;i<T;i++) // T为周期,单周期时长:pt*T 个工作周期;
{
if(i>t1&&RL)
RL=0;
if(i>t2&&GL)
GL=0;
if(i>t3&&BL)
BL=0;
delay();
}
}
}
坐板凳学习啦。 不懂C语言,还是谢谢二楼的朋友 不错,正好需要 学习2喽程序了 本帖最后由 chaily 于 2012-9-23 19:02 编辑
当然可以了,汇编也是很简单的,这里给出一个独立控制三路PWM的汇编程序:
;注意,三个输出口以低电平为有效输出,也就是当输出0%时为高电平输出,输出100%时为低电平输出。改变10H-12H的值可以控制三路PWM的占空比变化,例如当10H中的值从0-255变化时候,P1.0输出从0%-100%变化
;此程序中频率完全固定不变化,改变10H,11H,12H中的值仅改变三路输出的占空比,频率是完全恒定的,要改变频率,请自行改变定时器中断的值。这里的PWM波周期为 50us x 255=12750us,频率约为78Hz
DENG1 EQU P1.0;红灯输出口
DENG2 EQU P1.1;绿灯输出口
DENG3 EQU P1.2;蓝灯输出口
LIANGDU1 EQU 10H;红灯亮度值,也就是占空比的比值,从0-255变化
LIANGDU2 EQU 11H;绿灯亮度值,也就是占空比的比值,从0-255变化
LIANGDU3 EQU 12H;蓝灯亮度值,也就是占空比的比值,从0-255变化
ORG 0000H
LJMP RESET
ORG 000BH
LJMP Timer0Interrupt
RESET: ;复位程序
MOV SP,#60H
MOV P1,#0FFH ;P1置高
MAIN:;主程序
MOV LIANGDU1,#10H ;给红灯赋值10,这里是作为测试随便给的一个数值,10亮度很低
MOV LIANGDU2,#0FFH;给绿灯赋值FF,这里是作为测试随便给的一个数值,ff则P1.1输出低电平,控制占空比100%,灯全亮
MOV LIANGDU3,#00H ;给蓝灯赋值FF,这里是作为测试随便给的一个数值,00亮度为0,也就是熄灭
LCALL InitTimer0 ;调用打开定时器中断
AJMP $
InitTimer0:;50us定时器中断设置子程序
MOV TMOD,#01H
MOV TH0,#0FFH
MOV TL0,#0CEH
SETB EA
SETB ET0
SETB TR0
RET
Timer0Interrupt: ;50us 定时器中断子程序,用于实现三路PWM输出
PUSH ACC
PUSH PSW
MOV TH0,#0FFH
MOV TL0,#0CEH
CJNE R0,#00H,AA ;从这里开始是整个控制程序的精华。检测R0值是否等于0(或者说是否已经被减为0),等于0则下一条重新赋值255,不等于0则跳到AA
MOV R0,#255 ;R0赋值255
MOV R1,LIANGDU1 ;把红灯亮度值复制给R1
MOV R2,LIANGDU2 ;把绿灯亮度值复制给R2
MOV R3,LIANGDU3 ;把蓝灯亮度值复制给R3
AA:CJNE R1,#00H,BB;判断控制红灯的值是否(或是否被减为0)为0,是则下一条关闭红灯,否则跳到BB
SETB DENG1 ;关闭红灯
AJMP CC ;跳到CC检测绿灯
BB:CLR DENG1 ;打开(或继续打开)红灯
DEC R1 ;R1数值减1
CC:CJNE R2,#00H,DD;这里控制绿灯与上面红灯原理一样
SETB DENG2
AJMP EE
DD:CLR DENG2
DEC R2
EE:CJNE R3,#00H,FF ;这里控制蓝灯与上面的原理一样
SETB DENG3
AJMP GG
FF:CLR DENG3
DEC R3
GG:DEC R0 ;把R0的值减1,(R0的初始值是255)
POP PSW
POP ACC
RETI
END
多谢7楼的朋友 好好学习了! 频率会不会太低啊,
wmsky 发表于 2012-9-23 22:56 static/image/common/back.gif
频率会不会太低啊,
可以调嘛~如果采用STC11系列的,调整数从0-255压缩到0-100的话,上个1000Hz完全无压力!! 51干这个性能还是弱点要靠软件实现了
直接用定时器要更好些 chaily 发表于 2012-9-23 23:46 static/image/common/back.gif
可以调嘛~如果采用STC11系列的,调整数从0-255压缩到0-100的话,上个1000Hz完全无压力!! ...
自己用51 做軟PWM控制LED 慢亮 慢滅, 達不到最好的 頻率,8Khz ,能上15KHz更好, 而且在兩端 不好控制。0-10%90-100% wmsky 发表于 2012-9-24 14:18 static/image/common/back.gif
自己用51 做軟PWM控制LED 慢亮 慢滅, 達不到最好的 頻率,8Khz ,能上15KHz更好, 而且在兩端 不好控制 ...
2T或者1T的51机单路PWM可以做到,普通的12T的51机可以做10KHz以上的PWM,但是占空比不能实现1%的步进了,10%的步进还是可以的。 好多东西我都不懂,向各位学习了 额。。现在是24通道频率1.2K。。。。用的40Mhz晶振 之前用51做过舵机控制器,两个定时器,控制16路舵机
也就是每个定时器产生8路频率相同,占空比不同的PWM 学习程序!
页:
[1]