用UltraEdit配置C51编译器编译多个C51程序的方法

moyanqd

@echo off&&title 调用KEIL自动编译工程目录下的C源代码文件
color 1e
@rem %F：当前文件，包含全路径(如c:\temp\test.c)
@rem %P：当前文件的路径(如c:\temp)
@rem %N：当前文件的文件名(如test)
@rem %E：当前文件的扩展名(如.c)
@rem 用法 %p %n
@rem      %1 %2  


SET PATH=%PATH%;C:\KEIL\C51\BIN;C:\KEIL\C51\INC;C:\KEIL\C51\LIB
SET C51INC=C:\KEIL\C51\INC          
SET C51LIB=C:\KEIL\C51\LIB


SET PROJECT_PATH=%1
SET PROJECT_NAME=%2
SET SET_NUMBER=5



SET OUTPUT_NAME=%PROJECT_PATH%%PROJECT_NAME%.hex

if not exist "%PROJECT_PATH%\STARTUP.A51" copy "C:\Keil\C51\LIB\STARTUP.A51" "%PROJECT_PATH%">NUL&&echo Copy 'STARTUP.A51' to Project Folder and Add File to Project

set type=C
for /r "%PROJECT_PATH%" %%i in (*.%type%)do set/a number+=1
if %number% gtr 0 if %number% lss %SET_NUMBER% goto START
echo 工程文件目录下%type%类型的文件共有%number%个!
start /max "" explorer "%PROJECT_PATH%"
start /max "" notepad "%~dp0%~nx0"
start /max "" notepad "%PROJECT_PATH%\STARTUP.A51"
exit



:START
if exist "%PROJECT_PATH%%PROJECT_NAME%.hex" del "%PROJECT_PATH%%PROJECT_NAME%.hex"
if exist "%PROJECT_PATH%%PROJECT_NAME%.bin" del "%PROJECT_PATH%%PROJECT_NAME%.bin"


:ASSEMBLY

SetLocal EnableDelayedExpansion
for /r "%PROJECT_PATH%" %%i in (*.a51) do (
set OBJ1=!OBJ1!%%i
A51 %%i
@if errorlevel 2 exit/B 1
@if errorlevel 3 exit/B 1
)

:COMPILATION

SetLocal EnableDelayedExpansion
for /r "%PROJECT_PATH%" %%i in (*.c) do (
set OBJ2=!OBJ2!%%i
C51 %%i DB SB OE
@if errorlevel 2 exit/B 1
@if errorlevel 3 exit/B 1
)



BL51 %OBJ1:.a51=.obj,%%OBJ2:.c=.obj,%%C51LIB%\C51S.lib,%C51LIB%\C51FPS.lib TO %PROJECT_PATH%%PROJECT_NAME%.abs RAMSIZE(256)


@if errorlevel 2 exit/B 1
@if errorlevel 3 exit/B 1



OH51 %PROJECT_PATH%%PROJECT_NAME%.abs
C:\COMP51\HEX2BIN.EXE %PROJECT_NAME%.hex

echo.
echo GENERATING BINARY FILE: %PROJECT_PATH%%PROJECT_NAME%.bin
exit 0

moyanqd

复制另存为bat ，然后按照我发的老帖http://www.amobbs.com/thread-1706435-1-1.html的方法使用，N年前的那个帖子只能编译单个程序，现在升级可以编译多个程序了

william_rain

可以编译工程下的所有c文件了。学习了

moyanqd

坛子里有懂批处理的可以帮我好好看看，我还有个小问题请教，这个批处理年前就弄，弄到现在就是那个小问题一直没有解决，批处理高手帮我好好看看BL51开头的那句，我是硬加上一句来消除命令行最后的那个逗号的，有什么好办法没有啊？