|
发表于 2012-5-15 22:45:49
|
显示全部楼层
刚刚仿真了一下,问题不大。要仿真的话,元器件应该选择“...\tools\capture\library\pspice”目录下的,
表示是有spice模型的元器件,对应的“place part”对话框右下角有个pspice A/D的小图标。
spice模型:
*****************************************
.SUBCKT D1N4500 1 2
D1 1 2 DFWD
D1A 1 2 DXTRA
D1B 2 1 DLEAK
R1 1 2 1.66407G
.MODEL DFWD D
+ IS=71.94942E-15 N=0.960183 RS=0.236317 IKF=0.000237528
+ CJO=4.0000E-12 M=.3333 VJ=.75 ISR=96.49884E-15
+ NR=1.82557 BV=86.542 IBV=.3447 TT=6.6562E-9
.MODEL DXTRA D
+ IS = 68.81973E-12 RS = 28.47153E-3 N = 2.15458 IKF = 0.0531356
+ TT = 0 CJO = 0 VJ = 1 M = .5
+ EG = 1.11 XTI = 3 KF = 0 AF = 1
+ FC = .5 BV = 1E5 IBV = .001
.MODEL DLEAK D
+ IS = 5.810722E-15 RS = 0.1 N = 180.584 TT = 0
+ CJO = 0 VJ = 1 M = .5 EG = 1.11
+ XTI = 3 KF = 0 AF = 1 FC = .5
+ BV = 1E5 IBV = .001
.ENDS
*****************************************
*****************************************
* A = diode anode
* K = diode cathode
* C = BJT collector
* E = BJT emitter
.SUBCKT PS2505 A K C E PARAMS: REL_CTR=1
* PS2505 from NEC * RAP 6/97
D1 A D Demit ;Gallium arsenide infrared emitting diode
D2 D A Demit ;Gallium arsenide infrared emitting diode
Vsense D K 0 ;Diode Current sense -> IF
Hd R 0 Vsense 1
Rd R T 10K
Cd T 0 54.302p
* models CTR
Gpcg C B TABLE ;Photodetector {(IC vs IF) / Q1 BF}
+ {If(abs(V(T))<10m,
+ (abs(V(T))^1.68372145*exp(limit(5.46602664-137.521721*abs(V(T)),-50,50))*REL_CTR/100),
+ (abs(V(T))^0.441917*exp(limit(-1.54666-6.875337*abs(V(T)),-50,50))*REL_CTR/100))}
+ (0,0) (10,10)
Q1 C B E Qdtect ;phototransistor detector
Rdummy B 0 5G
.model Demit D IS=1.22E-14 N=1.638226 RS=0.757535 BV=6 IBV=10U
+ CJO=50P EG=1.424 TT=500N
.model Qdtect NPN IS=100P BF=100 NF=1.25 BR=20 TF=4.86968N TR=1.31131u
+ CJE=197.468P CJC=110.915P VAF=100 ISS=0 CJS=36.04p
.ends
*****************************************
|
本帖子中包含更多资源
您需要 登录 才可以下载或查看,没有帐号?注册
x
|