Alimy 发表于 2012-1-2 22:51:43

KeilC51生成的hex文件为何要将这些空间全部写0?

RT。。

看到hex文件反汇编回来时的最开始都会有这样一些代码:

LJMP@@

@@:
mov R0,#0x7f   ;(R0)=0x7f
clr A            ;(A)=0
@:
mov @R0,A      ;   ((R0))=0
djnz R0,@      ;      (R0)--   if((R0)!=0)goto @;


编译器这样做的目的是什么了?请哪位前辈指教下!

Alimy 发表于 2012-2-24 16:43:03

个人猜想:
清零00~7f的内部数据存储器。。备用变量空间和堆栈空间。。keil的编译器会默认把局部变量赋值为0,不会出现未知的值、、


/*测试程序*/

#include "reg52.h"

void test()
{
        int j;
        P1=j|0x3f;
}
void main()
{
        int i;
        P0=0x01;
        P0=i;
        test();
        return;
}


反汇编的结果,局部变量虽然没有赋给初值。但都默认为0了。。
Q0000:      LJMPQ0003                        ;0000   02 00 03
Q0003:      MOV   R0,#7FH                      ;0003   78 7F
            CLR   A                            ;0005   E4
_loops:       MOV   @R0,A                        ;0006   F6
            DJNZR0,_loops                  ;0007   D8 FD   初始化内部RAM空间
            MOV   SP,#0BH                      ;0009   75 81 0B设置栈顶
            LJMP_main                        ;000C   02 00 0F
_main:      MOV   P0,#01H                      ;000F   75 80 01
            MOV   P0,09H                     ;0012   85 09 80
            LCALL _test                        ;0015   12 00 19
            RET                              ;0018   22
_test:      MOV   A,0BH                        ;0019   E5 0B
            ORL   A,#3FH                     ;001B   44 3F
            MOV   P1,A                         ;001D   F5 90
            RET                              ;001F   22

所以Keil编译出来的代码会默认把未手动初始化的变量赋值为0。。


修改原因:图片无法正常显示,重新编辑。。

Alimy 发表于 2012-2-29 08:59:15

在网上发现一篇文章。。介绍了下STARTUP.A51文件的注释和详解。解释了上电复位的操作。其中就包括了用户初始化内存空间。

悲剧。貌似只有我一个人在这里自言自语。算是这个小问题的完结吧。

来源:http://blog.csdn.net/jiazhen/article/details/2260933

;------------------------------------------------------------------------------
; STARTUP.A51: 用户上电初始化程序
;------------------------------------------------------------------------------
;
; 用户定义需上电初始化的内存空间
;
; 使用以下EQU命令可定义在CPU复位时需用0进行初始化的内存空间
;
; ; IDATA 存储器的空间的绝对起始地址总是0.
IDATALEN EQU 80H ; 需用0进行初始化的IDATA存储器空间的字节数
;
XDATASTART EQU 0H ; XDATA存储器空间的绝对起始地址
XDATALEN EQU 0H ; 需用0进行初始化的XDATA存储器的空间字节数.
;
PDATASTART EQU 0H ; PDATA存储器的空间的绝对起始地址
PDATALEN EQU 0H ; 需用0进行初始化的PDATA存储器的空间字节数.
;
; 注意: IDATA 存储器的空间在物理上包括了8051单片机的DATA和BIT存储器空间.
; 听说至少要保证与C51编译器运行库有关的存储器的空间进行0初始化不知是否
;------------------------------------------------------------------------------
;
; 再入函数模拟初始化
;
; 以下用EQU指令定义了再入函数模拟堆栈指针的初始化
;
; 使用SMALL存储器模式时再入函数的堆栈空间.
IBPSTACK EQU 0 ; 使用SMALL存储器模式再入函数时将其设置成1.
IBPSTACKTOP EQU 0FFH+1 ; 将堆栈顶设置为最高地址+1.
;
; 使用LARGE存储器模式时再入函数的堆栈空间.
XBPSTACK EQU 0 ; 使用LARGE存储器模式再入函数时将其设置成1.
XBPSTACKTOP EQU 0FFFFH+1; 将堆栈顶设置为最高地址+1.
;
; 使用COMPACT存储器模式时再入函数的堆栈空间.
PBPSTACK EQU 0 ; 使用COMPACT存储器模式再入函数时将其设置成1.
PBPSTACKTOP EQU 0FFFFH+1; 将堆栈顶设置为最高地址+1.
;
;------------------------------------------------------------------------------
;
; 使用COMPACT存储器模式时64K字节XDATA存储器空间的分页定义
;
; 以下用EQU指令定义PDATA类型变量在XDATA存储器空间的页地址
; 使用EQU指令定义PFAGE时必须与L51连接定位器PDATA指令的控制参数一致
;
PPAGEENABLE EQU 0 ; 使用PDATA类型变量时将其设置成1.
PPAGE EQU 0 ; 定义页号.
;
;------------------------------------------------------------------------------
NAME ?C_STARTUP ; 模块名为?C_STAUTUP
?C_C51STARTUP SEGMENT CODE ; 代码
?STACK SEGMENT IDATA ; 堆栈
RSEG ?STACK ; 堆栈
随便打进的汉字有用就用吧有错就帮我改吧
欢迎光临 下岗农民 主页
DS 1
EXTRN CODE (?C_START) ; 程序开始地址
PUBLIC ?C_STARTUP
CSEG AT 0x8000 ; 定义用户程序的起始地址,用MON51仿真器时可能有用
?C_STARTUP: LJMP STARTUP1
RSEG ?C_C51STARTUP
STARTUP1:
;
; 初始化串口
MOV SCON,#40H
MOV TMOD,#20H
MOV TH1,#0fdH
SETB TR1
CLR TI
; 单片机上电IDATA内存清零如果不需要上电清零IDATA 可以注销IF到IFEDN之间的话句
; 或者修改IDTALEN的长度为了具有掉电保护功能不知IDTALEN多长为好
IF IDATALEN <> 0
MOV R0,#IDATALEN - 1
CLR A
IDATALOOP: MOV @R0,A
DJNZ R0,IDATALOOP
ENDIF
;
; 单片机上电XDATA内存清零如果不需要上电清零XDATA 可以注销IF到IFEDN之间的话句
; 或者修改XDATALEN的长度
IF XDATALEN <> 0
MOV DPTR,#XDATASTART
MOV R7,#LOW (XDATALEN)
IF (LOW (XDATALEN)) <> 0
MOV R6,#(HIGH (XDATALEN)) +1
ELSE
MOV R6,#HIGH (XDATALEN)
ENDIF
CLR A
XDATALOOP: MOVX @DPTR,A
INC DPTR
DJNZ R7,XDATALOOP
DJNZ R6,XDATALOOP
ENDIF
;
; 送PDATA存储器页面高位地址
IF PPAGEENABLE <> 0
MOV P2,#PPAGE
ENDIF
;
; 单片机上电PDATA内存清零如果不需要上电清零XDATA 可以注销IF到IFEDN之间的话句
; 或者修改PDATALEN的长度
IF PDATALEN <> 0
MOV R0,#PDATASTART
MOV R7,#LOW (PDATALEN)
随便打进的汉字有用就用吧有错就帮我改吧
欢迎光临 下岗农民 主页
CLR A
PDATALOOP: MOVX @R0,A
INC R0
DJNZ R7,PDATALOOP
ENDIF
;
; 设置使用SMALL存储器模式时再入函数的堆栈空间.
IF IBPSTACK <> 0
EXTRN DATA (?C_IBP)
MOV ?C_IBP,#LOW IBPSTACKTOP
ENDIF
;
; 设置使用LARGE存储器模式时再入函数的堆栈空间.
IF XBPSTACK <> 0
EXTRN DATA (?C_XBP)
MOV ?C_XBP,#HIGH XBPSTACKTOP
MOV ?C_XBP+1,#LOW XBPSTACKTOP
ENDIF
;
; 设置使用COMPACT存储器模式时再入函数的堆栈空间.
IF PBPSTACK <> 0
EXTRN DATA (?C_PBP)
MOV ?C_PBP,#LOW PBPSTACKTOP
ENDIF
;
; 设置堆栈的起始地址
MOV SP,#?STACK-1 ; 例如MOV SP,#4FH
;
; This code is required if you use L51_BANK.A51 with Banking Mode 4
; 如果你的程序使用了Mode 4 程序分组技术请启动下面的程序,不会吧你的程序超过64K 利害
; EXTRN CODE (?B_SWITCH0)
; CALL ?B_SWITCH0 ; init bank mechanism to code bank 0
; 程序从第一组bank 0 块开始执行
; 跳转到用户程序MAIN函数
LJMP ?C_START
END
;lINSHENGFENG
;2001_10_26

wjhhh 发表于 2012-2-29 09:35:02

不是“悲剧。”   “貌似只有我一个人在这里自言自语。”其实许多人都在受教,大侠除外(它们认为 算是 小问题)。看不懂汇编,但知道了可能“编译器会默认把局部变量赋值为0,不会出现未知的值”。多一些这类文章,我们的知识会越来越多。
    谢谢。

lovemini 发表于 2012-2-29 10:30:09

这个应该是C语言要求的吧。未初始化的内存都要为零

Alimy 发表于 2012-2-29 11:04:45

回复【4楼】wjhhh
-----------------------------------------------------------------------
多谢鼓励。。
其实我也不知道我的实验是不是对的(能解释问题)或者有意义的(有价值的)。

Alimy 发表于 2012-2-29 11:06:34

回复【5楼】lovemini
-----------------------------------------------------------------------
http://www.ourdev.cn/bbs/bbs_content.jsp?bbs_sn=4954836&bbs_page_no=1&search_mode=4&search_text=Alimy&bbs_id=9999



我没有读过C标准。。这里有位网友提出的问题。有的编译器可能不会直接对局部变量自动清零、
页: [1]
查看完整版本: KeilC51生成的hex文件为何要将这些空间全部写0?